MODULE Init;

​

 IMPORT Draw, Math, Strings, Forms;

​

 CONST

  width = 420; height = 600; (* canvas size *)

  cx = 200.0; cy = 200.0; (* ring position *)

  r1 = 190.0; (* outer ring radius *)

  r2 = 170.0; (* inner ring radius *)

  er = 5.0; (* particle radius *)

  em = 1.0; (* mass *)

  eq = 10000.0;  (* charge dimentionless *)

  dt = 0.005; (* euler time step *)

  ne = 60; (* amount of particles *)

  compCycles = 10; (* calculations in one frame *)

  forceTitle = "сила";

  dissipationTitle = "рассеяние энергии";

​

 TYPE

  Particle = RECORD x, y, vx, vy: REAL END;

​

 VAR

  time, force, dissipation: REAL;

  e: ARRAY ne OF Particle;

  sliderForce, sliderDis: Forms.Slider;

​

PROCEDURE SetFD;

BEGIN force := sliderForce.value; dissipation := sliderDis.value

END SetFD;

​

PROCEDURE R (e: Particle): REAL;

BEGIN RETURN Math.Sqrt(Math.IntPower(e.x, 2) + Math.IntPower(e.y, 2))

END R;

​

PROCEDURE Dist2 (e1, e2: Particle): REAL;

BEGIN RETURN Math.IntPower(e1.x - e2.x, 2) + Math.IntPower(e1.y - e2.y, 2)

END Dist2;

​

PROCEDURE Move;

VAR i, j: INTEGER; fx, fy, dr, r, d: REAL;

BEGIN

 FOR i := 0 TO ne - 1 DO

  e[i].x := e[i].x + e[i].vx * dt;

  e[i].y := e[i].y + e[i].vy * dt;

  (* electrostatic repeling of particles *)

  fx := 0.0; fy := 0.0;

  FOR j := 0 TO ne - 1 DO

   IF i # j THEN

    d := Dist2(e[i], e[j]);

    IF d < er * er * 100.0 THEN

     fx := fx + eq / d * Math.Sign(e[i].x - e[j].x);

     fy := fy + eq / d * Math.Sign(e[i].y - e[j].y);

    END

   END

  END;

  (* electrostatic attraction to the ring *)

  r := R(e[i]);

  dr := (r1 + r2)/2.0 - r;

  fx := fx + e[i].x * dr;

  fy := fy + e[i].y * dr;

  (* acceleration *)

  IF (e[i].x > 0.0) & (e[i].y > - 20.0) & (e[i].y < 20.0) THEN

   fy := fy + force

  END;

  (* dissipation *)

  fx := fx - e[i].vx * dissipation;

  fy := fy - e[i].vy * dissipation;

  (* velocity *)

  e[i].vx := e[i].vx + fx / em * dt;

  e[i].vy := e[i].vy + fy / em * dt;

 END

END Move;

​

PROCEDURE Restore;

VAR d: REAL; i: INTEGER; label: ARRAY 32 OF CHAR;

BEGIN

 (* calculation *)

 time := time + dt * FLT(compCycles);

 FOR i := 0 TO compCycles - 1 DO Move END;

 (* draw *)

 Draw.SetBackgroundRGB(255, 255, 255);

 (* acceleration block *)

 Draw.StrokeRGB(0, 0, 0);

 Draw.StrokeWidth(1);

 Draw.FillRGB(50, 50, 250);

 Draw.RectRounded(350.0, 180.0, 60.0, 40.0, 4.0);

 (* ring *)

 Draw.StrokeRGB(50, 50, 50);

 Draw.NoFill();

 Draw.StrokeWidth(1);

 Draw.Ellipse(cx, cy, r1 * 2.0, r1 * 2.0);

 Draw.Ellipse(cx, cy, r2 * 2.0, r2 * 2.0);

 (* particles *)

 Draw.NoStroke();

 Draw.Fill(0FFFF4444H);

 d := er * 2.0;

 FOR i := 0 TO ne-1 DO

  Draw.Ellipse(cx + e[i].x, cy + e[i].y, d, d)

 END;

 (* label *)

 Draw.FillRGB(0, 0, 0);

 Strings.RealToStringFixed(time, label, 1);

 Strings.Append(" s", label);

 Draw.String(label, 340.0, 40.0, 16);

END Restore;

​

PROCEDURE ParticlesDisposition;

VAR i: INTEGER;

BEGIN

 i := 0;

 WHILE i < ne DO

  e[i].x := Math.Sin(FLT(i) * 6.0 / 180.0 * Math.Pi()) * 180.0;

  e[i].y := Math.Cos(FLT(i) * 6.0 / 180.0 * Math.Pi()) * 180.0;

  INC(i)

 END

END ParticlesDisposition;

​

PROCEDURE Setup;

BEGIN

 Draw.SetSize(width, height);

 Draw.SetFrameRate(20);

END Setup;

​

BEGIN

 ParticlesDisposition;

 time := 0.0;

 force := 30.0;

 dissipation := 0.3;

 sliderForce := Forms.NewSlider(20, 420, 380, 44, forceTitle, 0., 300., 1., SetFD);

 sliderDis := Forms.NewSlider(20, 490, 380, 44, dissipationTitle, 0.1, 1.0, 0.05, SetFD);

 Forms.SetReal(sliderForce, force);

 Forms.SetReal(sliderDis, dissipation);

 Draw.SetSetupProc(Setup);

 Draw.SetDrawProc(Restore);

 Draw.Start

END Init.