MODULE WebDecoder;

(**

 project = "Modeller"

 organization = "Mobatec"

 contributors = "Mobatec"

 changes = ""

 issues = ""

​

**)

​

 IMPORT Log;

​

 CONST

  N = 16384;

  OldVersion = 0; ThisVersion = 1;

  Tag = "StdCoder.Decode "; (* first letter of Tag must not to appear within Tag again *)

  EOF = 255;

​

 TYPE

  FileName = ARRAY 256 OF CHAR;

​

 VAR

  code: ARRAY 64 OF CHAR;

  revCode: ARRAY 256 OF INTEGER;

  table: ARRAY N OF BYTE;

​

  str: ARRAY 1024 OF CHAR; bytestr: ARRAY 1024 OF BYTE; n: INTEGER;

  name: FileName;

​

PROCEDURE Decode* (VAR inout: ARRAY OF BYTE; VAR size: INTEGER; VAR fname: FileName): BOOLEAN;

​

VAR rdpos, res: INTEGER;

​

 PROCEDURE WriteByte (x: BYTE);

 BEGIN

  inout[size] := x; INC(size)

 END WriteByte;

​

 PROCEDURE Read (): BYTE;

  VAR x: INTEGER;

 BEGIN

  IF res = 0 THEN

   REPEAT x := inout[rdpos]; INC(rdpos);

    IF x = 0 THEN res := EOF END;

    x := revCode[x]

   UNTIL (x >= 0) OR (rdpos >= LEN(inout));

   IF rdpos >= LEN(inout) THEN res := 1 END

  END;

  IF res # 0 THEN x := 0 END;

  RETURN x

 END Read;

​

 PROCEDURE ReadHeader (*VAR type: BYTE*);

  VAR x, bit, i, j: INTEGER; ch: CHAR; tag: ARRAY 17 OF CHAR;

 BEGIN

  rdpos := 0; tag := Tag; i := 0;

  WHILE (rdpos < LEN(inout)) & (tag[i] # 0X) DO

   ch := CHR(inout[rdpos]); INC(rdpos);

   IF ch = tag[i] THEN INC(i) ELSIF ch = tag[0] THEN i := 1 ELSE i := 0 END

  END;

  IF rdpos < LEN(inout) THEN

   res := 0; i := 0; bit := 0; x := 0;

   REPEAT

    WHILE (res = 0) & (bit < 8) DO j := Read(); INC(x, LSL(j, bit)); INC(bit, 6) END;

    IF res = 0 THEN

     ch := CHR(x MOD 256); x := x DIV 256; DEC(bit, 8); fname[i] := ch; INC(i)

    END

   UNTIL (res # 0) OR (ch = 0X);

   j := Read();

   IF res = 0 THEN

    (* Utf8ToString(utf8, name); *)

    IF (j = ThisVersion) OR (j = OldVersion) THEN

     j := Read(); (* type := j *)

    ELSE res := 3

    END

   END

  ELSE res := 8

  END;

  res := ORD(rdpos >= LEN(inout))

 END ReadHeader;

​

 PROCEDURE SkipFileExt;

  VAR x, bit, i, j: INTEGER; ch: CHAR;

 BEGIN

  res := 0; i := 0; bit := 0; x := 0;

  REPEAT

   WHILE (res = 0) & (bit < 8) DO j := Read(); INC(x, LSL(j, bit)); INC(bit, 6) END;

   IF res = 0 THEN ch := CHR(x MOD 256); x := x DIV 256; DEC(bit, 8); INC(i) END

  UNTIL (res # 0) OR (ch = 0X)

 END SkipFileExt;

​

 PROCEDURE ReadFile;

  VAR hash, x, bit, i, j, len, sum, s: INTEGER; byte: BYTE;

 BEGIN

  res := 0; i := 0; len := 0;

  REPEAT x := Read(); len := len + LSL(x, 6 * i); INC(i) UNTIL (res # 0) OR (i = 6);

  i := 0;

  REPEAT table[i] := 0; INC(i) UNTIL i = N;

  bit := 0; hash := 0; sum := 0;

  WHILE (res = 0) & (len # 0) DO

   IF bit = 0 THEN x := Read(); bit := 6 END;

   IF ODD(x) THEN (* Incorrect prediction -> 1'xxxx'xxxx *)

    x := x DIV 2; DEC(bit);

    WHILE (res = 0) & (bit < 8) DO j := Read(); INC(x, LSL(j, bit)); INC(bit, 6) END;

    i := x MOD 256;

    IF i > 255 THEN i := i - 256 END;

    byte := i; x := x DIV 256; DEC(bit, 8);

    table[hash] := byte

   ELSE byte := table[hash]; x := x DIV 2; DEC(bit) (* correct prediction *)

   END;

   hash := (16 * hash + byte MOD 256) MOD N;

   WriteByte(byte); sum := (sum + byte MOD 256) MOD (16 * 1024); DEC(len)

  END;

  IF res = 0 THEN

   i := 0; s := 0;

   REPEAT x := Read(); s := s + LSL(x, 6 * i); INC(i) UNTIL (res # 0) OR (i = 6);

   IF (res = 0) & (s # sum) THEN res := 2 END

  END

 END ReadFile;

​

 BEGIN

  size := 0;

  ReadHeader(*t*);

  IF res = 0 THEN SkipFileExt;

   IF res = 0 THEN ReadFile END

  END;

  RETURN (res = 0) OR (res = EOF)

 END Decode;

​

PROCEDURE InitCodes;

 VAR i, j: INTEGER;

BEGIN

 j := 0;

 WHILE j # 256 DO revCode[j] := -1; INC(j) END;

 code[0] := "."; revCode[ORD(".")] := 0; code[1] := ","; revCode[ORD(",")] := 1;

 i := 2; j := ORD("0");

 WHILE j <= ORD("9") DO code[i] := CHR(j); revCode[j] := i; INC(i); INC(j) END;

 j := ORD("A");

 WHILE j <= ORD("Z") DO code[i] := CHR(j); revCode[j] := i; INC(i); INC(j) END;

 j := ORD("a");

 WHILE j <= ORD("z") DO code[i] := CHR(j); revCode[j] := i; INC(i); INC(j) END;

 ASSERT(i = 64)

END InitCodes;

​

BEGIN

 InitCodes

(* Test part: *)

 ;

 str := "StdCoder.Decode IJ4Sot0RsF5.,0 oV5R..X.....FOO,NHH9PTvQ176H8RDtQ,NM,NHTfM19

 R9vM,dP9vR,tQdPRBfN1,Qi....

 --- end of encoding ---";

 FOR n := 0 TO LEN(str) - 1 DO bytestr[n] := ORD(str[n]) END;

 IF Decode(bytestr, n, name) THEN Log.String("Done!");

  Log.Ln; Log.String("size of file = "); Log.Int(n); Log.Ln;

   Log.String("Name = "); Log.String(name); Log.Ln

 ELSE

  Log.String("Error")

 END

END WebDecoder.